VB.NET中的LINQ to XML

Dim productXML As XDocument = XDocument.Load( _
    Server.MapPath("~/App_Data/products.xml"))

Dim products As List(Of Product) = 'some query to select all products ?'

'set up Product properties here'
someProduct.ProductID = 'somehow get productid from XML'

Marc是对的,VB可以让你做很多好事.我自己就是C#家伙,但我刚刚敲了VB解决方案,看看如何为你做这件事.我已经发布了下面的代码并解释了关键部分. VB对Xml的功能给我留下了深刻的印象！

我在您的代码示例中看到您已经设法将Xml加载到XDocument中.完成XDocument.Load后,您可以使用一些特殊语法访问Xml文档.

对于初学者,我们希望从文档中获取所有产品;即全部<产品>元素.我们需要做以下事情：

Dim products = productsDoc...<Product>

这表示你想要所有<产品>文件中的元素.这为我们提供了一个IEnumerable XElements集合.

一旦我们从集合中提取单个产品,我们就会想要访问产品的价值,例如它的名称或价格.为此,我们需要执行以下操作：

' this gets the value of the price element within a product
product.<Price>.Value

这是一个完整的示例以及您要查看的预期输出：

Module Module1

    ' some products xml to use for this example
    Dim productsXml = <Xml>
                          <Product>
                              <Name>Mountain Bike</Name>
                              <Price>59.99</Price>
                          </Product>
                          <Product>
                              <Name>Arsenal Football</Name>
                              <Price>9.99</Price>
                          </Product>
                          <Product>
                              <Name>Formula One Cap</Name>
                              <Price>14.99</Price>
                          </Product>
                          <Product>
                              <Name>Robin Hood Bow</Name>
                              <Price>8.99</Price>
                          </Product>
                      </Xml>

    Sub Main()

        ' load the xml into an XDocument
        ' NOTE: this line isn't needed when using inline XML as per this example,' but I wanted to make this code easy to modify for reading in text files
        Dim productsDoc = System.Xml.Linq.XDocument.Parse(productsXml.ToString())

        ' get all <Product> elements from the XDocument
        Dim products = From product In productsDoc...<Product> _
                       Select product

        ' go through each product
        For Each product In products
            ' output the value of the <Name> element within product
            Console.WriteLine("Product name is {0}",product.<Name>.Value)
            ' output the value of the <Price> element within product
            Console.WriteLine("Product price is {0}",product.<Price>.Value)
        Next

    End Sub

End Module

程序输出是：

Product name is Mountain Bike
Product price is 59.99
Product name is Arsenal Football
Product price is 9.99
Product name is Formula One Cap
Product price is 14.99
Product name is Robin Hood Bow
Product price is 8.99

希望这有用.如果您想了解更多信息,请询问:-)

睡前很难写出连贯的东西！

大佬总结

以上是大佬教程为你收集整理的VB.NET中的LINQ to XML全部内容，希望文章能够帮你解决VB.NET中的LINQ to XML所遇到的程序开发问题。

如果觉得大佬教程网站内容还不错，欢迎将大佬教程推荐给程序员好友。

本图文内容来源于网友网络收集整理提供，作为学习参考使用，版权属于原作者。
如您有任何意见或建议可联系处理。小编QQ：384754419，请注明来意。